Çözüldü Fazla Veri İçeren Excel Çalışması

Sub SaatlikIsSayilari()

    Const sql As String = _
        "TRANSFORM Count(ToplamIsAdeti) " & _
        "SELECT Kullanici, Tarih " & _
        "FROM [Data$] " & _
        "WHERE Kullanici <> '' " & _
        "GROUP BY Kullanici, Tarih " & _
        "ORDER BY Tarih, Kullanici " & _
        "PIVOT Format(Hour(ToplamIsAdeti), '00') & ':00 - ' & Format(Hour(ToplamIsAdeti) + 1, '00') & ':00'"
   
    Sheets("Saatlik İş Sayıları-1").Cells.ClearContents
   
    Dim cn As Object
   
    Set cn = CreateObject("ADODB.Connection")
   
    cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=""Excel 12.0;HDR=YES"";Data Source=" & ThisWorkbook.FullName
   
    Set rs = cn.Execute(sql)
   
    For i = 0 To rs.Fields.Count - 1
        Sheets("Saatlik İş Sayıları-1").Cells(1, i + 1) = rs(i).Name
    Next
   
    Sheets("Saatlik İş Sayıları-1").[a2].CopyFromRecordset rs
   
    cn.Close
   
    Sheets("Saatlik İş Sayıları-1").Columns("A:Z").EntireColumn.AutoFit
End Sub

Sub IsBaslamaVeBitis()
    'Uyarı !!! Performans sorunu çıkabilir...
    Const sql As String = _
        "SELECT A.Kullanici, A.Tarih, " & _
        "(select Min(b.ToplamIsAdeti) from [Data$] B where b.kullanici = a.Kullanici And b.tarih = a.tarih and Hour(b.ToplamIsAdeti)=8) As [08:00-09:00 İlk İş]," & _
        "(select Max(c.ToplamIsAdeti) from [Data$] C where c.kullanici = a.Kullanici And c.tarih = a.tarih and Hour(c.ToplamIsAdeti)=17) As [17:00-18:00 Son iş]," & _
        "(select Max(d.ToplamIsAdeti) from [Data$] D where d.kullanici = a.Kullanici And d.tarih = a.tarih and Hour(d.ToplamIsAdeti)=12) As [12:00-13:00 Son iş]," & _
        "(select Min(e.ToplamIsAdeti) from [Data$] E where e.kullanici = a.Kullanici And e.tarih = a.tarih and Hour(e.ToplamIsAdeti)=13) As [13:00-14:00 ilk iş] " & _
        "FROM [Data$] A where A.Kullanici <> '' group by A.Kullanici, A.Tarih order by A.Tarih, A.Kullanici"
   
    Sheets("İş Başlama ve Bitiş-1").Cells.ClearContents
   
    Dim cn As Object
   
    Set cn = CreateObject("ADODB.Connection")
   
    cn.Open "Provider=Microsoft.ACE.OLEDB.12.0;Extended Properties=""Excel 12.0;HDR=YES"";Data Source=" & ThisWorkbook.FullName
   
    Set rs = cn.Execute(sql)
   
    For i = 0 To rs.Fields.Count - 1
        Sheets("İş Başlama ve Bitiş-1").Cells(1, i + 1) = rs(i).Name
    Next
   
    Sheets("İş Başlama ve Bitiş-1").[a2].CopyFromRecordset rs
   
    cn.Close
   
    Sheets("İş Başlama ve Bitiş-1").Columns("C:F").NumberFormat = "hh:mm:ss"
   
    Sheets("İş Başlama ve Bitiş-1").Columns("A:F").EntireColumn.AutoFit
   
End Sub